home *** CD-ROM | disk | FTP | other *** search
/ Suzy B Software 2 / Suzy B Software CD-ROM 2 (1994).iso / extras / programm / a56 / examples / sixcomb.a56 < prev    next >
Text File  |  1995-04-27  |  9KB  |  439 lines
  1. ;***************************************************************
  2. ; 
  3. ; A stereo reverb for the DSP56001 signal processor.  Based on,
  4. ; 
  5. ;    Moorer, James A. "About This Reverberation Business."
  6. ;    Computer Music Journal Vol 3, No. 2 (1979), pp. 13-28.
  7. ;
  8. ;   reprinted in,
  9. ;
  10. ;    Roads, Curtis, and Strawn, John, ed., _Foundations
  11. ;    of Computer Music_, pp. 605-639, MIT Press, 1985.
  12. ;    ISBN 0-262-68051-3 (paper)
  13. ;    ISBN 0-262-181142 (hard)
  14. ;
  15. ; Each comb filter uses a low-pass filter in the feedback path.
  16. ; The combs and all-pass filter delay lines use a prime-number
  17. ; of stages to improve diffusion.
  18. ;
  19. ; The output all-pass stage is replicated for left/right
  20. ; decorrelation.  Each side uses slightly different gains
  21. ; and delay lengths.  This works a lot better than just inverting
  22. ; one side and adding in the input.
  23. ;
  24. ; I left out the early-reflection FIR filter because I needed the cycles
  25. ; for other effects.
  26. ;
  27. ; Quinn Jensen (jensenq@qcj.icon.com)
  28. ;
  29. ;***************************************************************
  30.     psect    vectors        p:$0000:$0040
  31.     psect    hf_code        p:$0040:$0200
  32.     psect    hf_datax    x:$0000:$0040
  33.     psect    hf_datax1    x:$0040:$0100
  34.     psect    hf_datay    y:$0000:$0040
  35.     psect    hf_datay1    y:$0040:$0100
  36.     psect    midi_data    x:$0400:$1000
  37.     psect    lo_data        x:$1000:$F000
  38.     psect    lo_code        p:$F000:$FE00
  39.     psect    loader        p:$FE00:$FFFF
  40.     psect    iox        x:$FFC0:$FFFF
  41.     psect    ioy        y:$FFC0:$FFFF
  42. ;
  43. ; some oft-used constants
  44. ;
  45.     psect    hf_datax
  46. ffff    dc    $FFFF        ;used a lot for modulus
  47. ONE    equ    $7FFFFF        ;"one"
  48. one    dc    ONE        ;"one"
  49. ;
  50. ; L/R inputs and outputs
  51. ;
  52. in_l    dc    0.0      
  53. in_r    dc    0.0      
  54. out_l    dc    0.0      
  55. out_r    dc    0.0      
  56. ;
  57. ; recompute comb gains g1 and g2
  58. ;
  59. recalc_comb_gains
  60.     move        x:<constsp,r0
  61.     movec        x:<ffff,m0
  62.     move        x:lowpass_cutoff_start,b
  63.     move        x:lowpass_cutoff_slope,y1
  64.     move        x:comb_g,x1
  65.     move        #0.5,x0
  66.  
  67.     do    #6,recalc_loop
  68.       clr    a    (r0)+        ;skip over the modulus const
  69.       add    x0,a    b,y0
  70.       mac    x0,y0,a            ;g1 = .5 * b + .5
  71.       clr    a    a,y0        ;y0 = g1
  72.       add    x1,a    y0,y:(r0)+    ;store g1 in table
  73.       macr    -x1,y0,a        ;g2 = g(1-g1) = g - g*g1 with limiting
  74.       add    y1,b    a,y:(r0)+    ;update b, store g2 in table
  75. recalc_loop
  76.     rts
  77.  
  78.     psect    midi_data
  79. ;
  80. ; default values for midi-derived parameters
  81. ;
  82. lowpass_cutoff_start
  83.     dc    -0.3906250    ; ctl value of 39
  84. lowpass_cutoff_slope
  85.     dc    0.0468750    ; ctl value of 67
  86. comb_g
  87.     dc    0.8325507974    ; ctl value of 57
  88. ;
  89. ; preset comb-length arrays
  90. ;
  91. define(COMBLEN, `
  92. ; comb lenths $2,$3,$4,$5,$6,$7
  93. comblen_$1
  94.     dc    $2-1
  95.     dc    $3-1
  96.     dc    $4-1
  97.     dc    $5-1
  98.     dc    $6-1
  99.     dc    $7-1
  100. ')
  101.  
  102. COMBLEN(1, 383, 433, 467, 523, 557, 601)
  103. COMBLEN(2, 509, 577, 631, 701, 743, 797)
  104. COMBLEN(3, 683, 769, 839, 937, 991, 1069)
  105. COMBLEN(4, 919, 1021, 1117, 1249, 1319, 1427)
  106. COMBLEN(5, 1223, 1367, 1489, 1657, 1759, 1901)
  107. COMBLEN(6, 1627, 1823, 1987, 2213, 2341, 2539)
  108.  
  109. ;;;;;;;;;;;;;;;;;;;;;;;
  110. ; reverb filters
  111. ;;;;;;;;;;;;;;;;;;;;;;;
  112.  
  113. ;  Reverb filter lengths and coefficients     
  114. ;  6 comb reverb with prime delay lines
  115. ;  Sun Oct 24 13:53:51 1993
  116. ;  
  117. ;                          Sample rate        32.5520830 kHz      
  118. ;                          g                   0.8400000
  119. ;  
  120. ;                    status      STABLE       
  121. ;         delay      near prime lengths actual
  122. ;  stage   (ms)   len  high   low  best  delay        g1        g2
  123. ;  ---------------------------------------------------------------
  124. ;  Comb 1  50.0  1628  1637  1627  1627 49.981 0.3064583 0.5825750
  125. ;  Comb 2  56.0  1823  1823  1823  1823 56.003 0.3264583 0.5657750
  126. ;  Comb 3  61.0  1986  1987  1979  1987 61.041 0.3464583 0.5489750
  127. ;  Comb 4  68.0  2214  2221  2213  2213 67.983 0.3594792 0.5380375
  128. ;  Comb 5  72.0  2344  2347  2341  2341 71.916 0.3694792 0.5296375
  129. ;  Comb 6  78.0  2539  2539  2539  2539 77.998 0.4243750 0.4835250
  130. ;  All      6.0   195   197   193   193  5.929 0.7000000
  131.  
  132. ; COMB(name, length, modulus, g1, g2)
  133.  
  134. define(COMB, `
  135. ; storage for "$1" length=$2 modulus=$3 g1=$4 g2=$5
  136.  
  137.     psect    lo_data
  138.     align    $3
  139. $1d
  140. $1m    equ    $2-1
  141.     org    x:$1d+$1m
  142.     psect    hf_datax
  143. $1g1    equ    $4
  144. $1g2    equ    $5
  145. ')
  146.  
  147. COMB(c1, 1627, 2048, 0.3046875, 0.5812382)
  148. COMB(a1, 193, 256, 0.7000000, 0.0000000)
  149. COMB(c2, 1823, 2048, 0.3281250, 0.5616459)
  150. COMB(c3, 1987, 2048, 0.3515625, 0.5420536)
  151. COMB(c4, 2213, 4096, 0.3750000, 0.5224613)
  152. COMB(a2, 207, 256, 0.7500000, 0.0000000)
  153. COMB(c5, 2341, 4096, 0.3984375, 0.5028690)
  154. COMB(c6, 2539, 4096, 0.4218750, 0.4832767)
  155.  
  156.     psect    hf_datax
  157. a1r    dc    a1d
  158. a1md    dc    a1m
  159. a1g1d    dc    a1g1
  160. a2r    dc    a2d
  161. a2md    dc    a2m
  162. a2g1d    dc    a2g1
  163.     psect    hf_datay
  164. curaddrp
  165.     dc    curaddr
  166.     psect    hf_datax
  167. constsp    dc    consts
  168. lowstatep
  169.     dc    lowstate
  170.  
  171.     psect    hf_datax1
  172. curaddr
  173.     dc    c1d
  174.     dc    c2d
  175.     dc    c3d
  176.     dc    c4d
  177.     dc    c5d
  178.     dc    c6d
  179.  
  180.     psect    hf_datay1
  181. consts
  182.     dc    c1m
  183.     dc    c1g1
  184.     dc    c1g2
  185.     dc    c2m
  186.     dc    c2g1
  187.     dc    c2g2
  188.     dc    c3m
  189.     dc    c3g1
  190.     dc    c3g2
  191.     dc    c4m
  192.     dc    c4g1
  193.     dc    c4g2
  194.     dc    c5m
  195.     dc    c5g1
  196.     dc    c5g2
  197.     dc    c6m
  198.     dc    c6g1
  199.     dc    c6g2
  200.  
  201.     psect    hf_datax1
  202. lowstate
  203.     dc    0
  204.     dc    0
  205.     dc    0
  206.     dc    0
  207.     dc    0
  208.     dc    0
  209.  
  210. ;;;;;;;;;;;;;;;;;;;;;;;
  211. ; miscellaneous signals
  212. ;;;;;;;;;;;;;;;;;;;;;;;
  213.  
  214.     psect    hf_datax
  215. L_overall
  216.     dc    $7FFFFF
  217. R_overall
  218.     dc    $7FFFFF
  219.  
  220. ;;;;;;;;;;;;;;;;;;;;;;;
  221. ; signal vector
  222. ;;;;;;;;;;;;;;;;;;;;;;;
  223.     psect    hf_datax
  224.     align 8
  225. signal_vector
  226. Lin    dc    0.0
  227. Rin    dc    0.0
  228. Reverb_L
  229.     dc    0.0
  230. Reverb_R    
  231.     dc    0.0
  232.  
  233. Lout
  234.     dc    0
  235. Rout
  236.     dc    0
  237.  
  238.     psect hf_datay
  239. signal_vectorp
  240.     dc    signal_vector
  241. signal_mod
  242.     dc    4-1
  243.  
  244. gain_vectorsp
  245.     dc    gain_vectors
  246. ;;;;;;;;;;;;;;;;;;;;;;;
  247. ; gain matrix
  248. ;;;;;;;;;;;;;;;;;;;;;;;
  249.     psect    hf_datay1
  250. gain_vectors
  251. Reverb_gain_vector
  252. Reverb_Lin    dc 0.5
  253. Reverb_Rin    dc 0.5
  254. Reverb_Reverb_L    dc 0.0
  255. Reverb_Reverb_R    dc 0.0
  256.  
  257. Lout_gain_vector
  258. Lout_Lin    dc 0.0
  259. Lout_Rin    dc 0.0
  260. Lout_Reverb_L    dc ONE
  261. Lout_Reverb_R    dc 0.0
  262.  
  263. Rout_gain_vector
  264. Rout_Lin    dc 0.0
  265. Rout_Rin    dc 0.0
  266. Rout_Reverb_L    dc 0.0
  267. Rout_Reverb_R    dc -1.0
  268.  
  269. ;***************************************************************
  270. ;
  271. ;    init code - call hf_init at first and any time when
  272. ;    parameters change
  273. ;
  274. ;***************************************************************
  275.     psect    lo_code
  276.  
  277. hf_init
  278. ;
  279. ;    clear out the filter delay lines
  280. ;
  281. define(CLEAR_LINE, `
  282.     move        #$1d,r0
  283.     movec        #$1m,m0
  284.     jsr    clear_line_r0
  285. ')
  286.  
  287. CLEAR_LINE(c1)
  288. CLEAR_LINE(c2)
  289. CLEAR_LINE(c3)
  290. CLEAR_LINE(c4)
  291. CLEAR_LINE(c5)
  292. CLEAR_LINE(c6)
  293. CLEAR_LINE(a1)
  294. CLEAR_LINE(a2)
  295.     jsr    recalc_comb_gains
  296.     rts
  297.  
  298. clear_line_r0
  299.     clr    a
  300.     rep    #0
  301.       move        a,x:(r0)+
  302.     rts
  303.  
  304. ;***************************************************************
  305. ;
  306. ;    sample rate computations
  307. ;
  308. ;    Call hf_comp once per sample.
  309. ;    Globals in_l and in_r should have the left and right
  310. ;    input samples.  When hf_comp returns, out_l and out_r
  311. ;    will be ready.
  312. ;
  313. ;***************************************************************
  314.  
  315. ;
  316. ; fs = 32.552083 kHz
  317. ;
  318.     psect    hf_code
  319.  
  320. hf_comp
  321. ;
  322. ;    copy inputs
  323. ;
  324.     move        x:<in_l,a
  325.     move        a,x:<Lin
  326.     move        x:<in_r,a
  327.     move        a,x:<Rin
  328. ;
  329. ;    compute outputs using matrix multiply
  330. ;
  331. ; [reverb_in out_l out_r] = [gain_vector] * [signal_vector]
  332. ;
  333.     move        y:<signal_vectorp,r0
  334.     movec        y:<signal_mod,m0
  335.     move        y:<gain_vectorsp,r4
  336.     movec        x:<ffff,m4
  337.     move        x:<L_overall,y1        ;and wait for m4
  338.     clr    a    x:(r0)+,x0 y:(r4)+,y0
  339.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  340.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  341.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  342.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  343.     clr    a    a,b            ;b is reverb_in
  344.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  345.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  346.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  347.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  348.     clr    a    a,x1
  349.     mpy    x1,y1,a    x:<R_overall,y1
  350.     clr    a    a,x:<out_l
  351.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  352.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  353.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  354.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  355.     clr    a    a,x1
  356.     mpy    x1,y1,a
  357.     clr    a    a,x:<out_r
  358. ;
  359. ; r1    lowstate vector
  360. ; m1    -1
  361. ; r4    ptr to modulus,g1,g2 constants
  362. ; m4    -1
  363. ; r5    curaddr ptr
  364. ; m5    -1
  365. ; b    comb out accum
  366. ; x0    scaled comb in
  367. ;
  368. ;
  369. ;    set up reverb input
  370. ;
  371.     clr    b    b,x0            ;get reverb_in
  372.     move        #1.0/16,x1        ;allow 4 bits of headroom
  373.     mpyr    x0,x1,a                ;and 4 bits of noise
  374.     move        a,x0
  375.     move        x:<lowstatep,r1
  376.     movec        x:<ffff,m1
  377.     move        x:<constsp,r4
  378.     movec        m1,m4
  379.     move            y:<curaddrp,r5
  380.     movec        m1,m5
  381. ;
  382. ;    do the six combs
  383. ;
  384.     do    #6,comb_loop
  385.       move        x:(r5),r0        ;r0=curaddr
  386.       movec        y:(r4)+,m0        ;m0=modulus
  387.       move        x:(r1),x1 y:(r4)+,y1    ;x1=lowstate, y1=g1, wait for m0
  388.       move        x:(r0)+,y0        ;y0=delay out
  389.       add    y0,b        y0,a        ;a=delay out
  390.       macr    x1,y1,a        y:(r4)+,y1    ;a=out+g1*lowstate, y1=g2
  391.       clr    a          a,x:(r1)+ a,y0        ;y0=new lowstate
  392.       add    x0,a    r0,x:(r5)+        ;a=in, save ptr
  393.       macr    y0,y1,a                ;a=in+g2*g1*lowstate
  394.       move        a,x:-(r0)        ;store delay in (takes 2 cyc)
  395. comb_loop
  396. ;
  397. ;    scale
  398. ;
  399.     rnd    b    #$15,x0        ;scale by ~1/6
  400.     move        b,y0
  401.     mpyr    x0,y0,b
  402.     move        b,y1        ;save b for right chan
  403. ;
  404. ;    allpass L
  405. ;
  406.     move        x:<a1r,r0
  407.     movec        x:<a1md,m0
  408.     move        x:<a1g1d,x0
  409.     move        x:(r0),x1
  410.     macr    x0,x1,b    x1,a
  411.     move            b,y0
  412.     macr    -x0,y0,a b,x:(r0)+
  413.     asl    a          r0,x:<a1r
  414.     asl    a            ;get rid of the headroom
  415.     asl    a
  416.     asl    a
  417.     move        a,x:<Reverb_L
  418. ;
  419. ;    allpass R
  420. ;
  421.     tfr    y1,b    x:<a2r,r0
  422.     movec        x:<a2md,m0
  423.     neg    b    x:<a2g1d,x0
  424.     move        x:(r0),x1
  425.     macr    x0,x1,b    x1,a
  426.     move            b,y0
  427.     macr    -x0,y0,a b,x:(r0)+
  428.     asl    a    r0,x:<a2r
  429.     asl    a
  430.     asl    a
  431.     asl    a
  432.     move        a,x:<Reverb_R
  433. ;
  434. ;    done
  435. ;
  436.     rts
  437.  
  438.     end
  439.